RAM

Exemple de diagramme :

Ce diagramme montre les relations directes et indirectes entre toutes les variables du modèle en utilisant des flèches pour indiquer la direction de causalité. Les coefficients de régression entre les variables sont indiqués par des flèches à une tête. Les variances et covariances sont indiquées par des flèches à deux têtes. Les flèches à deux têtes qui pointent vers des variables endogènes représentent les termes d'erreur (par exemple $Y1=1.0F1+E1, \, \theta _1=var E1$).

Le modèle RAM (Reticular Action), modèle de Mc Ardle(1980), Mc Ardle et Mc Donald(1984), est le suivant ;

v=Av+u

où A est une matrice régulière et v et u sont des vecteurs aléatoires. Les variables dans v et u peuvent être manifestes ou latentes. Les variables endogènes correspondant aux composantes de v sont exprimées comme combinaison linéaire des variables restantes et des composantes d'un vecteur u de matrice de covariance P.

La matrice de covariance des variables manifestes s'écrit

$$C=J(I-A)^{-1}P(I-A)^{-1\prime} J^{\prime}$$

où J est la matrice de sélection.

Exemple : le diagramme précédent correspond aux équations structurelles suivantes

$$V1\, = \,1.0V7\,+\,U1$$

$$V2\,=\,.833V7\,+\,U2$$

$$V3\,=1.0V8\,+\,U3$$

$$V4\,=\,.833V8\,+\,U4$$

$$V5\,=\,1.0V9\,+\,U5$$

$$V6\,=\,\lambda V9\,+\,U6$$

$$V7\,=\,\gamma_1 V9\,+\,U7$$

$$V8\,=\,\beta V7\,+\,\gamma_2 V9\,+\,U8$$

$$V9\,=\,U9$$

et aux matrices

$$V\,= \left( \begin{array}{c} V1\\ V2\\ V3\\ V4\\ V5\\ V6\\ F1\\ F2\\ F3 \end{array} \right)$$

$$A\,= \left( \begin{array}{ccccccccc} 0&0&0&0&0&0&1&0&0\\ 0&0... ...0&0&\beta&0&\gamma _2\\ 0&0&0&0&0&0&0&0&0 \end{array} \right)$$

$$P\,= \left( \begin{array}{ccccccccc} \theta_1&0&\theta_5&0&0&... ...0&0&0&0&0&\psi_2&0\\ 0&0&0&0&0&0&0&0&\phi \end{array} \right)$$

L'option RAM transcrit un diagramme en une liste. On assigne des nombres aux "noeuds" du diagramme c'est à dire aux variables. RAM contient une liste de groupes de termes séparés par des virgules. Chaque ligne correspond à une flèche dans le diagramme. La première entrée de chaque ligne est le nombre de têtes de la flèche, la seconde entrée désigne la destination de la flèche, la troisième entrée désigne l'origine de la flèche, la quatrième entrée donne la valeur initiale du coefficient et la cinquième entrée donne un nom si le coefficient est un paramètre et non une constante. Si la cinquième entrée spécifie qu'il s'agit d'un paramètre alors la quatrième entrée n'est pas nécessaire parce que CALIS donnera une valeur initiale à ce paramètre.

Les n premiers nombres assignés aux variables dans le diagramme et dans le vecteur v doivent correspondre aux n variables manifestes de la matrice de covariance ou de corrélation entrée. Si l'on n'est pas sûr de l'ordre des variables manifestes dans Data, on utilise l'option VAR pour spécifier l'ordre des variables : chaque variable manifeste se verra attribuer dans le diagramme son rang dans la matrice de covariance ou de corrélation.

Ces entrées données sous forme de liste déterminent les éléments des matrices A et P. Le premier terme est le numéro de la matrice dans le modèle RAM (1:matrice A, 2:matrice P). Le second terme est le numéro de la ligne de la matrice où se situe l'élément. Le troisième terme est le numéro de la colonne de la matrice où se situe l'élément.

Si l'on ne spécifie ni le quatrième, ni le cinquième terme, le coefficient est supposé constant égal à 1 par défaut. En utilisant le même nom pour différents coefficients, on les contraint à être égaux.

Avec RAM on peut utiliser les commandes suivantes

VARNAMES (VNAMES) donne des noms aux variables latentes et aux erreurs. On ne peut utiliser qu'un VARNAMES avec chaque PROC CALIS. La matrice peut être spécifiée par l'entier 1 ou 2 (1:matrice A, 2:matrice P). Par exemple pour le diagramme précédent, on peut spécifier les variables latentes par les noms F1, F2, F3 et les variables d'erreurs par les noms E1, E2,..., E6, D1, D2 et D3 de la façon suivante :
VNAMES

1.

f1-f3,

2.

e1-e6 d1-d3;

Si dans RAM, VNAMES n'est pas spécifié, des noms seront assignés par défaut aux variables en utilisant les préfixes F, E et D.

PARAMETERS (PARMS) définit d'autres paramètres que ceux qui sont utilisés dans le modèle. On peut utiliser plusieurs PARAMETERS pour chaque PROC CALIS. La liste des noms de paramètres peut être suivie d'un signe égal et d'une liste de nombres. Ces nombres seront utilisés comme valeurs initiales des paramètres.

Exemple :
PARAMETERS alpha=.5 beta=-.5;

BOUNDS

On y exprime les minorations et les majorations. Les seuls opérateurs acceptés sont $<,\, >,\, >=$ et <=. On peut utiliser BOUNDS pour définir une contrainte pour tout paramètre dont le nom a été spécifié dans RAM ou qui est utilisé dans le modèle d'un INRAM=data set (voir plus loin).

Exemple :

BOUNDS

0.0<=a1-a9 x<=1.0,

-1.0<=c2-c5,

b1-b10 y>=0.0;

On doit séparer les contraintes par une virgule.

VAR donne la liste des variables manifestes qui doivent être analysées. Si VAR n'est pas précisé, toutes les variables manifestes sont analysées. On utilise VAR pour s'assurer que les variables manifestes apparaissent dans l'ordre correct pour RAM.

Ces commandes sont placées après la liste de RAM.

On ne peut utiliser qu'une seule fois RAM pour chaque PROC CALIS.

Exemple correspondant au diagramme précédent :

DATA CMAT(TYPE=COV);
TITLE "Stability of Alienation, Example in EQS and LISREL Guide";

   _TYPE_ = 'COV'; INPUT _NAME_ $ V1-V6;
   LABEL V1='Anomia (1967)' V2='Anomia (1971)' V3='Education'
         V4='Powerlessness (1967)' V5='Powerlessness (1971)'
         V6='Occupational Status Index';
   CARDS;
V1   11.834     .        .        .       .        .
V2    6.947    9.364     .        .       .        .
V3    6.819    5.091   12.532     .       .        .
V4    4.783    5.028    7.495    9.986    .        .
V5   -3.839   -3.889   -3.841   -3.625   9.610     .
V6  -21.899  -18.831  -21.748  -18.775  35.522  450.288
  ;

PROC CALIS COV DATA=CMAT TECH=NR EDF=931 ALL;
 TITLE3 "Model of BENTLER, 1985, p. 31";
ram
  1 1 7 1.,
  1 2 7 .833,
  1 3 8 1.,
  1 4 8 .833,
  1 5 9 1.,
  1 6 9 .5 lamb,
  1 7 9 -.5 gam1,
  1 8 7 .5 beta,
  1 8 9 -.5 gam2,
  2 1 1 3. the1,
  2 2 2 3. the2,
  2 3 3 3.the1,
  2 4 4 3. the2,
  2 5 5 3. the3,
  2 6 6 3. the4,
  2 1 3 .2 the5,
  2 2 4 .2 the5,
  2 7 7 4. psi1,
  2 8 8 4. psi2,
  2 9 9 6. phi;
vnames 1 f1-f3,
       2 e1-e6 d1-d3;
run;