COSAN

Le modèle COSAN est le suivant :

$$C\, = \,F_{1}P_{1}F_1^{'}\,+...+\,F_{m}P_{m}F_{m}^{'}$$

où C est la matrice de corrélation ou de covariance, chaque matrice F_k, k=1,...m, est le produit de n(k) matrices F_kj, j=1,...,n(k), et chaque matrice P_k est symétrique.

Après COSAN on tape les m termes matriciels séparés par des signes + selon l'addition des termes dans le modèle. Chaque terme matriciel contient les définitions des n(k)+1 matrices, F_kj et P_k, séparées par des astérisques * selon la multiplication des matrices dans le modèle. Les matrices F_kj^' du côté droit du produit sont redondantes et ne sont pas spécifiées sous COSAN. Chaque définition de matrice contient le nom de la matrice suivi entre parenthèses du nombre de colonnes de la matrice et optionnellement d'une ou deux propriétés, séparées par des virgules, décrivant la forme de la matrice. On peut choisir de spécifier comme première propriété de la matrice :

• DIA spécifie une matrice diagonale. Si la matrice n'est pas carrée, ceci décrit une sous matrice diagonale suivie d'une sous matrice rectangle nulle.
• GEN spécifie une matrice rectangle générale; c'est ce qui est adopté par défaut.
• IDE spécifie une matrice identité. Si la matrice n'est pas carrée, ceci décrit une sous matrice identité suivie d'une sous matrice rectangle nulle.
• LOW spécifie une matrice triangulaire inférieure; la matrice peut être rectangle.
• SYM spécifie une matrice symétrique; la matrice ne peut pas être rectangle.
• UPP spécifie une matrice triangulaire supérieure; la matrice peut être rectangle.
• ZDI spécifie une matrice "zéro:diagonale"; si la matrice n'est pas carrée, ceci décrit une sous matrice rectangulaire nulle suivie d'une sous matrice diagonale.
• ZID spécifie une matrice "zéro:identité"; si la matrice n'est pas carrée, ceci décrit une sous matrice rectangulaire nulle suivie d'une sous matrice identité.

La seconde propriété de la matrice décrit la transformation appliquée à la matrice. Si la seconde propriété n'est pas précisée, aucune transformation n'est effectuée. L'une des deux transformations suivantes peut être précisée :

• IMI si le modèle contient l'inverse de la différence entre la matrice identité et la matrice considérée ( (I-A)^-1).
• INV si le modèle contient l'inverse de la matrice.

On ne peut pas préciser INV ou IMI pour une matrice non carrée.

Exemple : COSAN j(9,ide)*a(9,gen,imi)*p(9,sym)

Commandes possibles avec COSAN :

• MATRIX
• VARNAMES
• BOUNDS
• PARAMETERS

MATRIX
Il doit y avoir au moins un MATRIX pour chaque matrice mentionnée dans COSAN sauf pour les matrices IDE et ZID. MATRIX spécifie les valeurs des éléments constants dans chaque matrice et donne des noms aux éléments qui sont des paramètres à estimer. On peut attribuer une valeur initiale à chaque paramètre en faisant suivre son nom d'un nombre entre parenthèses. Entre accolades se trouve la position de l'élément dans la matrice. Il y a plusieurs façons de spécifier la position des éléments.

• {i,j}=liste
  signifie que la liste de droite correspond aux éléments de la matrice {i,j}, {i+1,j+1},...,{i+n,j+n}. Le nombre d'éléments est défini par la longueur de la liste.
• {i,}=liste
  signifie que la liste de droite correspond aux éléments {i,j}, {i,j+1},...,{i,j+n} où j est la colonne de l'élément diagonal sur la ligne i pour une matrice DIA, ZDI ou UPP et j est la première colonne pour toutes les autres matrices. Pour une matrice symétrique, les éléments de la liste sont ceux de la partie inférieure de la matrice.
• {,j}=liste
  signifie que la liste de droite correspond aux éléments {i,j}, {i+1,j},...,{i+n,j} où i est la ligne de l'élément diagonal de la colonne j pour une matrice DIA, ZDI, SYM ou LOW et est la première ligne pour toute autre matrice.
• {,}=liste
  signifie que la liste correspond à tous les éléments possibles de la matrice en commençant par l'élément {1,1} et en lisant la matrice ligne après ligne. Les éléments possibles pour une matrice DIA ou ZDI sont les éléments diagonaux; pour une matrice UPP ou LOW ce sont les éléments au-dessus ou au-dessous de la diagonale et pour une matrice symétrique ce sont les éléments du triangle inférieur, le triangle supérieur en étant déduit automatiquement.

MATRIX ne peut être utilisé avec une matrice IDE ou ZID; pour toutes les autres matrices, chaque élément non spécifié sera supposé nul. Il peut y avoir plus d'un MATRIX pour chaque matrice mentionnée dans COSAN; si différentes définitions sont données à un élément matriciel, c'est la dernière définition qui compte.

Pour l'exemple de la page 5, le modèle spécifié dans COSAN étant le modèle RAM, on obtient :

DATA CMAT(TYPE=COV);
TITLE "Stability of Alienation, Example in EQS and LISREL Guide";

   _TYPE_ = 'COV'; INPUT _NAME_ $ V1-V6;
   LABEL V1='Anomia (1967)' V2='Anomia (1971)' V3='Education'
         V4='Powerlessness (1967)' V5='Powerlessness (1971)'
         V6='Occupational Status Index';
   CARDS;
V1   11.834     .        .        .       .        .
V2    6.947    9.364     .        .       .        .
V3    6.819    5.091   12.532     .       .        .
V4    4.783    5.028    7.495    9.986    .        .
V5   -3.839   -3.889   -3.841   -3.625   9.610     .
V6  -21.899  -18.831  -21.748  -18.775  35.522  450.288
  ;

PROC CALIS COV DATA=CMAT TECH=NR EDF=931 ALL;
 TITLE3 "Model of BENTLER, 1985, p. 31";
 cosan j(9,ide)*a(9,gen,imi)*p(9,sym);
  matrix a
     {,7} = 1. .833 5*0. beta(.5),
     {,8} = 2*0. 1. .833,
     {,9} = 4*0. 1. lamb gam1-gam2(.5 2*-.5);
  matrix p
     {1,1} = the1 the2 the1-the4(6*3.),
     {7,7} = psi1-psi2 phi(2*4. 6.),
     {3,1} = the5(.2),
     {4,2} = the5(.2);
  run;