Comment estimer les constantes
dans les équations structurelles?

On peut estimer les constantes (en anglais "intercept") d'un système d'équations structurelles en appliquant CALIS à la matrice de covariance non corrigée par la moyenne (UCOV) augmentée d'une variable INTERCEP constante égale à 1. Calis contient les options UCOV et AUGMENT (ou AUG) pour calculer et analyser une matrice UCOV augmentée.
Exemple : le modèle suivant est spécifié par deux équations contenant deux variables endogènes Q et P et trois variables exogènes D, F et Y;

$$Q = \alpha _1 + \beta _1 P + \gamma _1 D$$

$$Q = \alpha _2 + \beta _2 P + \gamma _2 F + \gamma _3 Y$$

 

title 'equations avec constantes';

data food;
input q p d f y;
 label Q='Food Consumption per Head'
       P='Ratio of Food Prices to General Price'
       D='Disposable Income in Constant Prices'
       F='Ratio of Preceding Years Prices'
       Y='Time in Years 1922-1941';
cards;
 98.485  100.323  87.4  98.0   1
 99.187  104.264  97.6  99.1   2
102.163  103.435  96.7  99.1   3
101.504  104.506  98.2  98.1   4
104.240   98.001  99.8 110.8   5
103.243   99.456 100.5 108.2   6
103.993  101.066 103.2 105.6   7
 99.900  104.763 107.8 109.8   8
100.350   96.446  96.6 108.7   9
102.820   91.228  88.9 100.6  10
 95.435   93.085  75.1  81.0  11
 92.424   98.801  76.9  68.6  12
 94.535  102.908  84.6  70.9  13
 98.757   98.756  90.6  81.4  14
105.797   95.119 103.1 102.3  15
100.225   98.451 105.1 105.0  16
103.522   86.498  96.4 110.5  17
 99.929  104.016 104.4  92.5  18
105.223  105.769 110.7  89.3  19
106.232  113.490 127.1  93    20
;
proc calis ucov aug data=food all;
lineqs
q=alph1 intercep + beta1 p + gamma1 d + e1,
p=alpha2_b intercep + gamma2_b f +gamma3_b y + _b q +e2;
parameters alpha2 beta2 gamma2 gamma3;
alpha2_b = -alpha2 / beta2;
gamma2_b = -gamma2 / beta2;
gamma3_b = -gamma3 / beta2;
_b = 1 / beta2;
std
 e1-e2 = eps1-eps2;
cov
 e1-e2 = eps3;
bounds
eps1-eps2 >= 0;
run;

L'option AUG ne peut être utilisée que lorsque UCOV, UCORR ou NOINT est spécifié.